Innhald

# ARBEIDSDAGAR.INTL

Returnerer datoen som er rekna ut frå ein startdato med eit visst tal på arbeidsdagar før eller etter startdatoen. Utrekninga kan ta med helg og heilagdagar som fridagar.

### Syntaks

ARBEIDSDAG.INTL(StartDato; Dagar[; Vekeslutt][; Heilagdagar])

StartDato: Datoen som utrekninga skal byrja frå.

Dagar er talet på arbeidsdagar. Ein positiv verdi står for dagar etter startdagen, ein negativ verdi for dagar før startdagen.

Vekeslutt er ein valfri parameter – eit tal eller ein streng som vert brukt for å visa kva dagar som høyrer til vekeslutt og såleis ikkje er arbeidsdagar. Vekeslutt er eit tal eller ein streng som viser når det er vekeslutt. Talverdiane indikerer desse vekesluttdagane:

Tal 1 til 7 for to-dagars vekeslutt og 11 til 17 for eitt-dags vekeslutt.

Tal | Helg
--- | ---
1 eller ingen | Laurdag og søndag
2 | Søndag og måndag
3 | Måndag og tysdag
4 | Tysdag og onsdag
5 | Onsdag og torsdag
6 | Torsdag og fredag
7 | Fredag og laurdag
11 | Berre søndag
12 | Berre måndag
13 | Berre tysdag
14 | Berre onsdag
15 | Berre torsdag
16 | Berre fredag
17 | Berre laurdag

Ein annan måte å definera fridagar på, er å bruka helgestrengar. Strengen må ha sju (7) teikn – null (0) for arbeidsdagar og ein (1) for fridagar. Kvart tal representerer ein vekedag. Første dagen er måndag. Strengen «1111111» kan ikkje brukast. Strengen «0000011» definerer laurdag og søndag som fridagar.

Fridagar er ei valfri liste med datoar som er fridagar. Lista kan gjevast som eit celleområde.

Når datoar vert skrivne inn som ein del av ein formel, vert skråstrekar og bindestrekar oppfatta som matematiske teikn. Difor vert datoar som inneheld desse teikna ikkje oppfatta som datoar, noko som fører til feil i utrekningane. For at datoar skal oppfattast som datoar, bruk DATO-funksjonen, for eksempel DATO(1954;7;20) eller bruk ISO 8601-notasjon i doble hermeteikn, for eksempel "1954-07-20". Ikkje bruk lokale skrivemåtar som for eksempel "20.07.54" sjølv om dei kanskje fungerer korrekt i oppsettet ditt. På andre maskiner med anna oppsett for datoar, kan dette føre til feil.

Det er mogleg å laga eintydige omformingar for dato og klokkeslett i utvida format med skiljeteikn i ISO 8601. Viss feilen #VERDI! kjem opp, fjernar du merkinga for Lag #VERDI!-feil i LibreOffice → Innstillingar Verktøy → Innstillingar → LibreOffice Calc → Formel, knappen Detaljar … i området «Detaljerte innstillingar for utrekning» i listeboksen Omform frå tekst til tal.

### Eksempel

Kva dato kjem 20 arbeidsdagar etter 13. desember 2016? Skriv inn startdatoen i C3 og talet på arbeidsdagar i D3.

Helgeparameteren (eit tal) kan vere tom eller definerast som 1 for standard fridagar – laurdag og søndag.

Cellene F3 til J3 inneheld fem (5) fridagar i jula og nyttåret i datoformatet: 24. desember 2016; 25 desember 2016; 26. desember 2016; 31. desember 2016; 1. januar 2017.

=ARBEIDSDAG.INTL(C3;D3;;F3:J3) returnerer 11. januar 2017 i resultatcella, for eksempel D6. (Bruk datoformat for cella).

Bruk helgeparameteren 7 for å definere fredag og laurdag som fridagar.

=ARBEIDSDAG.INTL(C3;D3;7;F3:J3) returnerer 15. januar 2017 med 7 som helgeparameter.

Bruk helgeparameteren 11 for å definere søndag som einaste fridag.

=ARBEIDSDAG.INTL(C3;D3;11;F3:J3) returnerer 9. januar 2017.

Alternativt kan strengen "0000001" brukast for søndag som einaste fridag.

=ARBEIDSDAG.INTL(C3;D3;"0000001";F3:J3) returnerer 9. januar 2017.

Funksjonen kan brukast utan dei to valfrie parameterane – vekedag og fridagar – ved å sløyfa dei:

=ARBEIDSDAG.INTL(C3;D3) gjev resultatet: 10. januar 2017.

#### Teknisk informasjon

Denne funksjonen har vore tilgjengeleg sidan LibreOffice 4.3.

Denne funksjonen er ikkje ein del av standarden Open Document Format for kontorprogram (OpenDocument) Versjon 1.3. del 4: Omrekna formel (OpenFormula)-format. Namnerommet er

COM.MICROSOFT.WORKDAY.INTL

Liknande emne

WORKDAY.INTL (ARBEIDSDAG.INTL) wikiside.

Dato- og klokkeslettfunksjonar

DATO

DATODIFF

DATOVERDI

DAG

DAGAR

DAGAR360

DAGAR.I.MÅNADEN

DAGAR.I.ÅRET

PÅSKEDAG

DAG.ETTER

MÅNADSSLUTT

TIME

ERSKOTÅR

ISOVEKENR

MINUTT

MÅNAD

MÅNADAR

NETTO.ARBEIDSDAGAR

NETTO.ARBEIDSDAGAR.INTL

NO

SEKUND

TID

TIDSVERDI

IDAG

VEKEDAG

VEKENR

VEKENR_EXEL2003

VEKENR_OOO

VEKER

VEKER.I.ÅRET

ARBEIDSDAG

ARBEIDSDAGAR.INTL

ÅR

ÅRDEL

TAL.PÅ.ÅR